home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / dc / dxromp.mf < prev    next >
Text File  |  1994-04-12  |  4KB  |  104 lines
  1. % This is DXROMP.MF in text format, as of March 24, 1992
  2. %
  3. % DC fonts Version 1.1 (prerelease of EC fonts)
  4. %
  5. %          [ heavily borrowed from the Computer Modern Roman family of
  6. %            fonts by D. E. Knuth ]
  7. %
  8. % Content:
  9. %
  10. %  some special roman characters (different from italic variants)
  11. %
  12. %    & ? spanish ?
  13. %
  14.  
  15.  
  16. dcchar "Ampersand";
  17. beginchar("&",14u#,asc_height#,0);
  18. italcorr x_height#*slant-serif_fit# - if serifs: .4u# else: 1.5u# fi;
  19. adjust_fit(0,serif_fit#);
  20. pickup tiny.nib; pos2(slab,-90); x2=4u; bot y2r=-o;
  21. if not hefty:(x,y2l)=whatever[z2r,(w-5u,x_height)]; x2l:=x; fi
  22. if serifs: pos0(fudged.hair,0);
  23.  rt x0r+jut=hround(w-.9u); top y0=x_height;
  24.  pos1(fudged.hair,0); z1=whatever[z0,(.6[x0,x2],0)];
  25.  y1=max(y0-1.5bracket-.2x_height,2/3x_height);
  26.  filldraw stroke z0e---z1e...{left}z2e;  % short diagonal
  27. else: pickup fine.nib; pos1(.25[slab,flare],-15); rt x1r=hround(w-2u);
  28.  y1r=good.y .75[bar_height,x_height]; x1l:=good.x x1l; y1l:=good.y y1l;
  29.  top z2'l=(x2l,tiny.top y2l); bot z2'r=(x2r,tiny.bot y2r);
  30.  filldraw stroke term.e(2',1,right,1,4); fi  % short diagonal and terminal
  31. pickup tiny.nib; numeric slope,theta,reduced_hair;
  32. slope=(h-2vair-slab)/10.5u; theta=angle(-slope,1);
  33. reduced_hair=max(tiny.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
  34. lft x3r=hround .75u; x5=.5[x3r,x6l]; lft x6r=hround .5(w-u);
  35. x3l-x3r=curve-tiny; pos6(reduced_hair,180);
  36. pos5(vair,theta); y5=.5h;
  37. ellipse_set(2l,3l,4l,5l); ellipse_set(2r,3r,4r,5r);
  38. pos7(vair,270); top y7l=h+o; x7=.45[x6r,x8r];
  39. pos8(fudged.stem,30); x8l=good.x(x8l+3.5u-x8); y8r=y6;
  40. ellipse_set(7l,6l,5',5l);
  41. filldraw stroke z2e{left}...z3e{up}...z4e---z5e...{up}z6e
  42.  ...z7e{left}...z8e{down};  % bowls
  43. pos10(slab,90); x10=w-3.5u; bot y10l=-o;
  44. pos9(fudged.stem,angle(z8-z10)-90);
  45. z9=.5[z8,z10]+(1.75u,0) rotated(angle(z8-z10)+90);
  46. filldraw stroke z8e{down}...z9e{z10-z8}...{right}z10e;  % long diagonal
  47. if serifs: pickup crisp.nib; pos10'(slab,90); z10'=z10;
  48.  pos11(fudged.hair,180); rt x11l=hround(w-u); y11=.5bar_height;
  49.  filldraw stroke z10'e{right}...{up}z11e;  % terminal
  50.  numeric inner_jut; if rt x6l+.5u<lft x0l-1.5jut: inner_jut=1.5jut;
  51.  else: rt x6l+.5u=lft x0l-inner_jut; fi
  52.  dish_serif(0,1,a,.6,inner_jut,b,.5,jut)(dark);  % serif
  53. else: pickup fine.nib; pos10'(slab,90); z10'=z10;
  54.  pos11(Vround .5[slab,flare],90);
  55.  rt x11=hround(r-letter_fit-u); bot y11l=vround .07bar_height-o;
  56.  filldraw stroke term.e(10',11,right,1,4); fi  % terminal
  57. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  58.  
  59. dcchar "Question mark";
  60. beginchar("?",8.5u#,asc_height#,0);
  61. italcorr .8asc_height#*slant;
  62. adjust_fit(0,0);
  63. pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
  64. lft x7l=hround(.5w-.25u-.5dot_size); bot y8l=0; z7=z8; dot(7,8);  % dot
  65. numeric bot_width;
  66. bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  67. pickup fine.nib; pos2(vair,90); pos3(curve,0);
  68. pos4(vair,-90); pos5(bot_width,0); pos6(bot_width,0);
  69. x2=x4=x5=x6=x7; rt x3r=hround(w-u); bot y6=1+.25[top y8r,x_height];
  70. top y2r=h+oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
  71. {{interim superness:=more_super;
  72. filldraw stroke pulled_super_arc.e(2,3)(superpull)
  73.  & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
  74. if serifs: pos1(hair,180); pos0(flare,180);
  75.  lft x1r=hround u; y1=y3; bulb(2,1,0);  % bulb
  76. else: pos1(Vround 5/7[vair,flare],110);
  77.  lft x1r=hround u; top y1r=vround .9[y6,top y2r];
  78.  filldraw stroke term.e(2,1,left,1,4); fi  % terminal
  79. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  80.  
  81. dcchar "Spanish open question mark";
  82. beginchar(oct"276",8.5u#,asc_height#-desc_depth#,desc_depth#);
  83. adjust_fit(0,0);
  84. pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
  85. lft x7l=hround(.5w-.25u-.5dot_size); top y8r=h; z7=z8; dot(7,8);  % dot
  86. numeric top_width;
  87. top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  88. pickup fine.nib; pos2(vair,270); pos3(curve,180);
  89. pos4(vair,90); pos5(top_width,180); pos6(top_width,180);
  90. x2=x4=x5=x6=x7; lft x3r=hround u; top y6=.25[bot y8l,h-x_height]-1;
  91. bot y2r=-d-oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
  92. {{interim superness:=more_super;
  93. filldraw stroke pulled_super_arc.e(2,3)(superpull)
  94.  & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}};  % arc and stem
  95. if serifs: pos1(hair,0); pos0(flare,0);
  96.  rt x1r=hround(w-u); y1=y3; bulb(2,1,0);  % bulb
  97. else: pos1(Vround 5/7[vair,flare],-70);
  98.  rt x1r=hround(w-u); bot y1r=vround .9[y6,bot y2r];
  99.  filldraw stroke term.e(2,1,right,1,4); fi  % terminal
  100. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  101.  
  102. endinput;
  103.  
  104.